eval_added event: change interface to traceID\tjobsetID\tevaluationID

I was not going to break the interface until I noticed
the current implementation uses the string literal \t.

t/Hydra/Event/EvalAdded.t

@@ -0,0 +1,112 @@
+use strict;
+use warnings;
+use Setup;
+use Hydra::Event;
+use Hydra::Event::EvalAdded;
+use Test2::V0;
+use Test2::Tools::Exception;
+use Test2::Tools::Mock qw(mock_obj);
+
+
+my $ctx = test_context();
+my $builds = $ctx->makeAndEvaluateJobset(
+    expression => "basic.nix",
+    build => 1
+);
+
+
+subtest "Parsing eval_added" => sub {
+    like(
+        dies { Hydra::Event::parse_payload("eval_added", "") },
+        qr/three arguments/,
+        "empty payload"
+    );
+    like(
+        dies { Hydra::Event::parse_payload("eval_added", "abc123") },
+        qr/three arguments/,
+        "one argument"
+    );
+    like(
+        dies { Hydra::Event::parse_payload("eval_added", "abc123\tabc123") },
+        qr/three arguments/,
+        "two arguments"
+    );
+    like(
+        dies { Hydra::Event::parse_payload("eval_added", "abc123\tabc123\tabc123\tabc123") },
+        qr/three arguments/,
+        "four arguments"
+    );
+    like(
+        dies { Hydra::Event::parse_payload("eval_added", "abc123\tabc123\t123") },
+        qr/should be an integer/,
+        "not an integer: second position"
+    );
+    like(
+        dies { Hydra::Event::parse_payload("eval_added", "abc123\t123\tabc123") },
+        qr/should be an integer/,
+        "not an integer: third position"
+    );
+    is(
+        Hydra::Event::parse_payload("eval_added", "abc123\t123\t456"),
+        Hydra::Event::EvalAdded->new("abc123", 123, 456)
+    );
+};
+
+subtest "interested" => sub {
+    my $event = Hydra::Event::EvalAdded->new("abc123", 123, 456);
+
+    subtest "A plugin which does not implement the API" => sub {
+        my $plugin = {};
+        my $mock = mock_obj $plugin => ();
+
+        is($event->interestedIn($plugin), 0, "The plugin is not interesting.");
+    };
+
+    subtest "A plugin which does implement the API" => sub {
+        my $plugin = {};
+        my $mock = mock_obj $plugin => (
+            add => [
+                "evalAdded" => sub {}
+            ]
+        );
+
+        is($event->interestedIn($plugin), 1, "The plugin is interesting.");
+    };
+};
+
+subtest "load" => sub {
+    my $jobset = $builds->{"empty_dir"}->jobset;
+    my $evaluation = $builds->{"empty_dir"}->jobsetevals->first();
+
+    my $event = Hydra::Event::EvalAdded->new("traceID", $jobset->id, $evaluation->id);
+
+    $event->load($ctx->db());
+    is($event->{"trace_id"}, "traceID", "The Trace ID matches");
+    is($event->{"jobset_id"}, $jobset->id, "The Jobset ID matches");
+    is($event->{"evaluation_id"}, $evaluation->id, "The Evaluation ID matches");
+
+
+    # Create a fake "plugin" with a evalAdded sub, the sub sets these
+    # "globals"
+    my $passedTraceID;
+    my $passedJobset;
+    my $passedEvaluation;
+    my $plugin = {};
+    my $mock = mock_obj $plugin => (
+        add => [
+            "evalAdded" => sub {
+                my ($self, $traceID, $jobset, $evaluation) = @_;
+                $passedTraceID = $traceID;
+                $passedJobset = $jobset;
+                $passedEvaluation = $evaluation;
+            }
+        ]
+    );
+
+    $event->execute($ctx->db(), $plugin);
+    is($passedTraceID, "traceID", "We get the expected trace ID");
+    is($passedJobset->id, $jobset->id, "The correct jobset is passed");
+    is($passedEvaluation->id, $evaluation->id, "The correct evaluation is passed");
+};
+
+done_testing;

t/scripts/hydra-eval-jobset/notifications.t

@@ -67,13 +67,18 @@ subtest "on the initial evaluation" => sub {
     is($listener->block_for_messages(0)->()->{"channel"}, "build_queued", "expect 2/4 builds being queued");
     is($listener->block_for_messages(0)->()->{"channel"}, "build_queued", "expect 3/4 builds being queued");
     is($listener->block_for_messages(0)->()->{"channel"}, "build_queued", "expect 4/4 builds being queued");
-    is($listener->block_for_messages(0)->()->{"channel"}, "eval_added", "the evaluation has completed");
+
+    expectEvent($listener, "eval_added", sub {
+        is($_->{"jobset_id"}, $jobset->get_column('id'), "the jobset ID matches");
+        is($_->{"evaluation_id"}, $evaluation->get_column('id'), "the evaluation ID matches");
+    });
     is($listener->block_for_messages(0)->()->{"channel"}, "builds_added", "new builds have been scheduled");
     is($listener->block_for_messages(0)->(), undef, "there are no more messages from the evaluator");
 };
 
 subtest "on a subsequent, totally cached / unchanged evaluation" => sub {
     ok(evalSucceeds($jobset), "evaluating for the second time");
+    my $evaluation = $builds->{"stable-job-queued"}->jobsetevals->first();
 
     my $traceID;
     expectEvent($listener, "eval_started", sub {
@@ -103,7 +108,9 @@ subtest "on a fresh evaluation with changed sources" => sub {
     $builds->{"stable-job-failing"}->discard_changes();
 
     ok(evalSucceeds($builds->{"variable-job"}->jobset), "evaluating for the third time");
-    is($listener->block_for_messages(0)->()->{"channel"}, "eval_started", "the evaluation started");
+    expectEvent($listener, "eval_started", sub {
+        is($_->{"jobset_id"}, $jobset->get_column('id'), "the jobset ID matches");
+    });
 
     # The order of builds is randomized when writing to the database,
     # so we can't expect the list in any specific order here.